Script zum herunterfahren-sichern-starten einer VM

[TSCH]

Hallo,

anbei mal mein neues Standard-Script zum herunterfahren einer VM.

****************************************************************

@echo off

:: Stand 2009-07-03
:: Batch (2.x) für VMs-Backups die einfach überschrieben werden
:: Definition der Variablen
:: Übergabe von vmdir, vmname (=vmxname.vmx)
:: !!! Groß-/Kleinschreibung beachten bei Datastore und VMX-Datei !!!

set USER=admin
set PASS=TesT

set DATASTORE=[VM]
set VMLW=D:
set VMDIR=%1
set VMNAME=%2
set COPYLW=\\192.168.1.34\vm


:: Sicherheitschecks

:: Ist der Backup-Server überhaupt erreichbar ?
ping 192.168.1.34
if errorlevel=1 goto backupoff

:: VMX-Datei vorhanden ?
if not exist %VMLW%\%VMDIR%\%VMNAME%\%VMNAME%.VMX goto errhost

:: VM gestartet ?
if not exist %VMLW%\%VMDIR%\%VMNAME%\*.vmem goto vmoff

:: VM "sanft" herunterfahren
vmrun -T server -h https://127.0.0.1:8333/sdk -u %USER% -p %PASS% stop "%DATASTORE% %VMNAME%/%VMNAME%.VMX" -soft

:: Der VM etwas Zeit zum herunterfahren verschaffen
ping -n 60 localhost > nul

:: VM synchronisieren mit Zielverzeichnis
robocopy "%VMLW%\%VMDIR%\%VMNAME%" "%COPYLW%\VM2\%VMNAME%" /MIR /NP /ZB /R:5 /TEE /Log:"%COPYLW%\LOG\%VMNAME%.txt"

:: Fehlerabfrage von robocopy
if errorlevel 16 (echo !!! SCHWERER FEHLER !!! > elv.txt
blat elv.txt -to tsch@sagichnich.de -subject %VMNAME%
goto end)
if errorlevel 8 (echo !! Fehlerhafte Kopien !! > elv.txt
blat elv.txt -to tsch@sagichnich.de -subject %VMNAME%
goto end)

:: VM wieder starten
call vmrun -T server -u %USER% -p %PASS% -h https://127.0.0.1:8333/sdk start "%DATASTORE% %VMNAME%/%VMNAME%.VMX"
goto end

:vmoff
echo VM war ausgeschaltet > d:\elv.txt
blat d:\elv.txt -to tsch@sagichnich.de -subject %VMNAME%
goto end

:backupoff
echo Backup-Medium nicht erreichbar > d:\elv.txt
blat d:\elv.txt -to tsch@sagichnich.de -subject "%VMNAME% Backup-LW"
goto end

:errhost
echo VMX-Datei nicht gefunden > d:\elv.txt
blat d:\elv.txt -to tsch@sagichnich.de -subject %VMNAME%

:end

****************************************************************

Noch ein paar Voraussetzungen.

Das Tool BLAT ermöglicht den Versand eines Textes als Mail aus der Kommandozeile.
(http://www.blat.net/)

Robocopy siehe http://en.wikipedia.org/wiki/Robocopy.

Verbesserungsvorschläge jeder Art sind willkommen.